Official Controls (Imports of High Risk Food and Feed of Non-Animal Origin) (Amendment of Commission Implementing Regulation (EU) 2019/1793) (England) Regulations 2022 Reading list

A work package focussed on the Official Controls (Imports of High Risk Food and Feed of Non-Animal Origin) (Amendment of Commission Implementing Regulation (EU) 2019/1793) (England) Regulations 2022, made available on 17 November 2022, subject to the Made negative procedure. Scrutiny period described by Bicameral instruments (clock stops if both Houses rise).

Read the legislation.

Read the Explanatory Memorandum.

The reading list is currently empty.

Work package identifier

https://id.parliament.uk/4FwRNX6G

SPARQL queries used by this page

A work package

# We declare the Parliament and ID namespaces.
        PREFIX : <https://id.parliament.uk/schema/>
        PREFIX id: <https://id.parliament.uk/>

# We select the properties we want to appear in results. The asterisk will select all properties from the query.
        SELECT * WHERE {
        # We find all papers with a name and a work package.
        ?paper a :WorkPackagedThing .  
        ?paper :name ?paperName ;
        :workPackagedThingHasWorkPackage ?workPackage.

# We specify that a paper might have a web link. 
        OPTIONAL {?paper :workPackagedThingHasWorkPackagedThingWebLink ?workPackagedThingWebLink.}
  
        # We specify that a paper might have a laying with a laid date. We also specify that a laying will have a procedure step.  
        OPTIONAL {?paper :laidThingHasLaying ?laying.
        ?laying :layingDate ?laidDate;
        :businessItemHasProcedureStep ?step.
    
        # We specify that the laying will have one of two steps - 'Laid before the House of Commons' or 'Notification from Department announcing the publication of the draft laid before the House of Commons'. 
        FILTER (?step in (id:isWn7s3K, id:cspzmb6w))}

# We look for work packages with a procedure and the procedure's name.   
        ?workPackage :workPackageHasProcedure ?procedure.
        ?procedure :name ?procedureName.

# We specify that a work package may have a calculcation style with it's name but that a calculation style is not required. 
        OPTIONAL{ ?workPackage :workPackageHasCalculationStyle ?calculationStyle. 
        ?calculationStyle :name ?calculationStyleName. }

# We specify a specific work package using its ID. 
        FILTER (?workPackage in (id:4FwRNX6G))
        }

A list of business items in a work package with a link, actualising steps in the reading list collection

# We declare the Parliament and ID namespaces.
        PREFIX : <https://id.parliament.uk/schema/>
        PREFIX id: <https://id.parliament.uk/>

# We select the relevant properties we want to appear in  results. 
        SELECT ?paper ?paperName ?workPackage ?businessItem ?businessItemLink ?businessItemProcedureStep ?businessItemDate ?businessItemProcedureStepName?legislature ?legislatureName ?commonsId ?lordsId WHERE {
        # We find all papers with a name and a work package.
        ?paper a :WorkPackagedThing ;  
        :name ?paperName ;
        :workPackagedThingHasWorkPackage ?workPackage.

# We specify a specific work package using its ID. 
        FILTER (?workPackage IN (id:4FwRNX6G))

# We find business items associated with the work package.    
        ?workPackage :workPackageHasBusinessItem ?businessItem.
  
        # We specify that business items must have a web link and that we're also looking for a business item's procedure step. 
        ?businessItem :businessItemHasBusinessItemWebLink ?businessItemLink;
        :businessItemHasProcedureStep ?businessItemProcedureStep.

# We specify that business items might have a date but it is not required. 
        OPTIONAL {?businessItem :businessItemDate ?businessItemDate}

# We look for business items that are part of the 'Reading list' step collection. This means only work packages that have a business item actualising a step from that step collection will appear in the results.
        ?businessItemProcedureStep :procedureStepHasProcedureStepCollectionMembership/:procedureStepCollectionMembershipHasProcedureStepCollection  id:Ji8bWVUj.

# We look for the names of procedure steps that are actualised by a business item. 
        ?businessItemProcedureStep :name ?businessItemProcedureStepName.
  
        # We specify whether a procedure step belongs to a legislature and specify the results should show the legislature's name. 
        OPTIONAL {?businessItemProcedureStep :procedureStepInLegislature ?legislature.
        ?legislature :name ?legislatureName.}

# We specify whether a procedure step belongs to the House of Commons. 
        OPTIONAL {?businessItemProcedureStep :procedureStepHasHouse ?commonsId.
        # We specify the House ID for the House of Commons.
        FILTER (?commonsId IN (id:1AFu55Hs))}
  
        # We specify whether a procedure step belongs to the House of Lords.   
        OPTIONAL {?businessItemProcedureStep :procedureStepHasHouse ?lordsId.
        # We specify the House ID for the House of Lords.    
        FILTER (?lordsId IN (id:WkUWUBMx))} }

# We order the results by business item date.  
        ORDER BY ?businessItemDate