'Bicameral instruments (clock stops if both Houses rise)' calculation style Work packages before Parliament

See the 'Bicameral instruments (clock stops if both Houses rise)' calculation on Parliamentary Time.

There are 77 work packages.

Subscribe to RSS Download CSV

Work packages per page: 20 50 100

English Devolution and Community Empowerment Act 2026 (Consequential Amendments) (Precepts) (England) Regulations 2026

A work package, made available on 23 October 2026, subject to the Made negative procedure.
Intimate Image Reports (Trusted Flagger) Regulations 2026

A work package, made available on 22 October 2026, subject to the Made negative procedure.
Marine Licensing (Exempted Activities and Fees) (Amendment) Regulations 2026

A work package, made available on 22 October 2026, subject to the Made negative procedure.
Marine Licensing (Notices Appeals) (Amendment) Regulations 2026

A work package, made available on 22 October 2026, subject to the Draft affirmative procedure.
Sentencing Act 2020 (Prison Sanctions) Regulations 2026

A work package, made available on 22 October 2026, subject to the Draft affirmative procedure.
Environmental Permitting (England and Wales) (Amendment) (England) Regulations 2026

A work package, made available on 20 October 2026, subject to the Draft affirmative procedure.
North Atlantic Salmon Conservation Organization (Immunities and Privileges) Order 2026

A work package, made available on 20 October 2026, subject to the Draft affirmative procedure.
North-East Atlantic Fisheries Commission (Immunities and Privileges) Order 2026

A work package, made available on 20 October 2026, subject to the Draft affirmative procedure.
Social Security (Persons Detained in Hospital) (Amendment) Regulations 2026

A work package, made available on 20 October 2026, subject to the Draft affirmative procedure.
Authorised Investigators (Complaints and Misconduct) Regulations 2026

A work package, made available on 19 October 2026, subject to the Made negative procedure.
Code of Practice (Right of Trade Unions to Access Workplaces) Order 2026

A work package, made available on 19 October 2026, subject to the Made negative procedure.
Consumer Subscription Contracts (Cancellation and Information) Regulations 2026

A work package, made available on 19 October 2026, subject to the Draft affirmative procedure.
Digital Markets, Competition and Consumers Act 2024 (Subscription Contracts) (Consequential Amendments) Regulations 2026

A work package, made available on 19 October 2026, subject to the Draft affirmative procedure.
School Teachers’ Pay and Conditions (England) Order 2026

A work package, made available on 16 October 2026, subject to the Made negative procedure.
Scotland Act 1998 (Specification of Functions and Transfer of Property etc.) (Amendment) Order 2026

A work package, made available on 16 October 2026, subject to the Made negative procedure.
Scottish Administration (Offices) Order 2026

A work package, made available on 16 October 2026, subject to the Made negative procedure.
Tribunal Procedure (Upper Tribunal) (Amendment) Rules 2026

A work package, made available on 16 October 2026, subject to the Made negative procedure.
Building (Local Authority Charges and Amendments Relating to Charging) (England) Regulations 2026

A work package, made available on 15 October 2026, subject to the Made negative procedure.
First-tier Tribunal and Upper Tribunal (Chambers) (Amendment No. 2) Order 2026

A work package, made available on 15 October 2026, subject to the Made negative procedure.
Port of Tyne Harbour Revision Order 2026

A work package, made available on 15 October 2026, subject to the Made negative procedure.

Showing 1 - 20 of 77.

Previous Next

Calculation style identifier

https://id.parliament.uk/FPPYJ9iv

SPARQL queries used by this page

A calculation style

A count of a calculation style's current work packages

# We declare the Parliament and ID namespaces.
PREFIX : <https://id.parliament.uk/schema/>
PREFIX id: <https://id.parliament.uk/>

# We select the properties we want to appear in results. 
# If all properties are required, an asterisk can be used between SELECT and WHERE instead of listing properties.
# We count the number of distinct work packages for a calculation style, excluding work packages that have business items with steps in the 'Procedure concluded' collection.
SELECT ( COUNT( DISTINCT ?workPackage ) AS ?count ) WHERE {

# We find all calculation styles with their names and work packages.
  # We exclude calculation styles that have no work packages.
  ?calculationStyle a :CalculationStyle;
  :name ?calculationStyleName;
  :calculationStyleHasWorkPackage ?workPackage.

# We filter the results to only include the calculation style with ID FPPYJ9iv.
  FILTER ( ?calculationStyle IN ( id:FPPYJ9iv ))

# We find the work packaged things of the work packages and their names.
  ?workPackage :workPackageHasWorkPackagedThing ?workPackagedThing.
  ?workPackagedThing :name ?workPackagedThingName.

# We find the making available business item, if there is one, of the work packages and it's date. 
  OPTIONAL {
    ?workPackage :workPackageHasBusinessItem ?businessItem .
    ?businessItem :businessItemHasProcedureStep ?step;
    :businessItemDate ?madeAvailableDate.
    FILTER ( ?step IN ( id:isWn7s3K, id:cspzmb6w, id:ITNO9JWr, id:otscOTzB ) )
  }

# We find the procedure of the work packages and the procedure names.
  ?workPackage :workPackageHasProcedure ?procedure.
  ?procedure :name ?procedureName.

# We exclude work packages that have business items with steps in the 'Procedure concluded' collection.
  # This limits results to work packages that are currently before Parliament.
  MINUS {  
    ?workPackage   :workPackageHasBusinessItem ?bi2.
    ?bi2 :businessItemHasProcedureStep ?stepId2.
    ?stepId2 :procedureStepHasProcedureStepCollectionMembership/:procedureStepCollectionMembershipHasProcedureStepCollection id:TRohjSuI
  }

}

A list of a calculation style's current work packages with limit and offset for pagination

# We declare the Parliament and ID namespaces.    
PREFIX : <https://id.parliament.uk/schema/>
PREFIX id: <https://id.parliament.uk/>

# We select the properties we want to appear in results.
# If all properties are required, an asterisk can be used between SELECT and WHERE instead of. 
# Distinct is used to ensure that work packages are not duplicated in the results.
SELECT DISTINCT ?calculationStyle ?calculationStyleName ?workPackage ?combinedDate ?workPackagedThing ?workPackagedThingName ?procedure ?procedureName (BOUND(?stepId3) AS ?hasCommitteeConcernsFlag)   
(BOUND(?stepId4) AS ?hasMotionTabledFlag) WHERE {

# We find all calculation styles with their names and work packages.
  ?calculationStyle a :CalculationStyle;
  :name ?calculationStyleName;
  :calculationStyleHasWorkPackage ?workPackage.

# We filter the results to only include the calculation style with ID FPPYJ9iv.
  FILTER ( ?calculationStyle IN ( id:FPPYJ9iv ) )

# We find the work packaged things of the work packages and their names.
  ?workPackage :workPackageHasWorkPackagedThing ?workPackagedThing.
  ?workPackagedThing :name ?workPackagedThingName.

# We find the procedure of the work packages and the procedure names.
  ?workPackage :workPackageHasProcedure ?procedure.
  ?procedure :name ?procedureName.

# We find the making available business item, if there is one, of the work packages and it's date.
  OPTIONAL {?workPackage :workPackageHasBusinessItem ?businessItem .
    ?businessItem :businessItemHasProcedureStep ?step;
    :businessItemDate ?businessItemDate.
    # We filter business items that actualise steps set out as making available steps such as 'Laid before the House of Commons'.
    FILTER ( ?step IN ( id:isWn7s3K, id:cspzmb6w, id:ITNO9JWr, id:otscOTzB ) )
  }
  
  # Some work packages have one or more available business items in one work package, one being earlier than the other.
  # We find the earliest available business item, if there is one, of the work packages and it's date.
  OPTIONAL {
    ?workPackage :workPackageHasBusinessItem ?businessItem2 .
    ?businessItem2 :businessItemHasProcedureStep ?step2;
    :businessItemDate ?businessItemDate2.
    # We filter business items that actualise the 'Brought to the attention of Parliament' step which may be the earliest available business item of a work package in the treaties procedure.
    FILTER ( ?step2 IN ( id:AmYrFxwO ) )
  }

# We exclude work packages that have business items with steps in the 'Procedure concluded' collection.
  # This limits results to work packages that are currently before Parliament.
  MINUS {
    ?workPackage :workPackageHasBusinessItem ?bi2.
    ?bi2 :businessItemHasProcedureStep ?stepId2.
    ?stepId2 :procedureStepHasProcedureStepCollectionMembership/:procedureStepCollectionMembershipHasProcedureStepCollection id:TRohjSuI
  }

# We check to see if the work package has a business item with a step in the 'Committee concerns' collection.
  OPTIONAL {
    ?workPackage :workPackageHasBusinessItem ?bi3 .
    ?bi3 :businessItemHasProcedureStep ?stepId3 .
    ?stepId3 :procedureStepHasProcedureStepCollectionMembership/
    :procedureStepCollectionMembershipHasProcedureStepCollection id:7CBVQcZF
  }

# We check to see if the work package has a business item with a step in the 'Motions tabled' collection.
  OPTIONAL {
    ?workPackage :workPackageHasBusinessItem ?bi4 .
    ?bi4 :businessItemHasProcedureStep ?stepId4 .
    ?stepId4 :procedureStepHasProcedureStepCollectionMembership/
    :procedureStepCollectionMembershipHasProcedureStepCollection id:l3g2umNB
  }

# We combine the two business item dates into one date for ordering purposes.  
  BIND(COALESCE( ?businessItemDate, ?businessItemDate2 ) AS ?combinedDate )
} 
# We order results by the combined date of the making available business items, with the most recent first, and then by the name of the work packaged thing.  
ORDER BY DESC(?combinedDate) ?workPackagedThingName

# We limit the number of results returned and offset the results by a certain number for pagination purposes.
LIMIT 20 OFFSET 0