Investment Exchanges, Clearing Houses and Central Securities Depositories (Amendment) (EU Exit) Regulations 2018

There is 1 work package.

Investment Exchanges, Clearing Houses and Central Securities Depositories (Amendment) (EU Exit) Regulations 2018

A work package, laid by the HM Treasury on 30 November 2018, subject to the Proposed negative statutory instrument procedure. Scrutiny period described by Proposed negative statutory instruments.

Work packageable thing identifier

https://id.parliament.uk/fJnkoeNZ

SPARQL queries used by this page

PREFIX id: <https://id.parliament.uk/>
       PREFIX : <https://id.parliament.uk/schema/>
       PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
       PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
       select ?workPackage ?WorkPackagedThing ?workPackagedThingName ?MadeAvailableDate ?procedure ?procedureName ?webLink ?SIprefix ?SINumber ?SIYear ?CommandPrefix ?CommandPaperNumber  where {
         ?WorkPackagedThing a :WorkPackagedThing;
                            :name ?workPackagedThingName;
                            :workPackagedThingHasWorkPackage ?workPackage.
         ?workPackage :workPackageHasProcedure ?procedure.
         ?procedure :name ?procedureName. 
   optional {?WorkPackagedThing :workPackagedThingHasWorkPackagedThingWebLink ?webLink.}
   optional {?WorkPackagedThing :statutoryInstrumentPaperPrefix ?SIprefix}
   optional {?WorkPackagedThing :statutoryInstrumentPaperNumber ?SINumber}
   optional {?WorkPackagedThing :statutoryInstrumentPaperYear ?SIYear}
   optional {?WorkPackagedThing :treatyCommandPaperNumber ?CommandPaperNumber}
   optional {?WorkPackagedThing :treatyCommandPaperPrefix ?CommandPrefix}
         optional {?workPackage :workPackageHasBusinessItem ?businessItem .
                   ?businessItem :businessItemHasProcedureStep ?step;
                          :businessItemDate ?MadeAvailableDate.
                   filter (?step in (id:isWn7s3K, id:cspzmb6w, id:ITNO9JWr, id:otscOTzB))}
   filter (?WorkPackagedThing in (id:fJnkoeNZ)) }

PREFIX id: <https://id.parliament.uk/>
PREFIX : <https://id.parliament.uk/schema/>
    
SELECT ?workPackage ?workPackagedThing ?workPackagedThingName ?combinedDate ?procedure ?procedureName ?calculationStyle ?calculationStyleName ?layingBody ?layingBodyName WHERE {

?workPackagedThing a :WorkPackagedThing;
	:name ?workPackagedThingName;
	:workPackagedThingHasWorkPackage ?workPackage.

VALUES ?workPackagedThing { id:fJnkoeNZ }

OPTIONAL {
    	?workPackagedThing :laidThingHasLaying ?laying .
    	?laying :businessItemHasProcedureStep id:cspzmb6w ;
        :layingHasLayingBody ?layingBody .
    	?layingBody :name ?layingBodyName .
	}

?workPackage :workPackageHasProcedure ?procedure.
	?procedure :name ?procedureName.

OPTIONAL {	
    	?workPackage :workPackageHasBusinessItem ?businessItem .
		?businessItem :businessItemHasProcedureStep ?step;
		:businessItemDate ?businessItemDate.
		VALUES ?step {
    		id:isWn7s3K
   			id:cspzmb6w
    		id:ITNO9JWr
    		id:otscOTzB
		}
  	}

OPTIONAL {    
    	?workPackage :workPackageHasBusinessItem ?businessItem2 .
		?businessItem2 :businessItemHasProcedureStep ?step2;
		:businessItemDate ?businessItemDate2.
        VALUES ?step2 {id:AmYrFxwO}
      	}

BIND( COALESCE ( ?businessItemDate, ?businessItemDate2) AS ?combinedDate )

OPTIONAL {
    	?workPackage :workPackageHasCalculationStyle ?calculationStyle. 
		?calculationStyle :name ?calculationStyleName. 
  	}
}

ORDER BY DESC(?combinedDate) ?workPackagedThingName