Medical Act 1983 Work packageable things

1983 c. 54. An Act of Parliament gaining Royal Assent on 26 July 1983.

Read the enabling legislation at legislation.gov.uk.

Instruments listed here are those laid since the start of the 2017-19 session, subject to parliamentary procedure.

There are 7 work packageable things.

Work packageable things per page: 20 50 100

Medical Profession (Responsible Officers) (Amendment) Regulations 2025
General Medical Council (Registration Appeals Panels Procedure) (Amendment) Rules Order of Council 2024
General Medical Council (Applications for General Practice and Specialist Registration) (Amendment) Regulations Order of Council 2024
General Medical Council (Miscellaneous Amendments) Order of Council 2024
Eligibility and Registration of General Practitioners and Specialist Medical Practitioners (Amendment) Order of Council 2022
Amendments Relating to the Provision of Integrated Care Regulations 2019
General Medical Council (Miscellaneous Amendments) Order of Council 2017

Showing 1 - 7 of 7.

Previous Next

Enabling legislation identifier

https://id.parliament.uk/HYrHvhwp

SPARQL queries used by this page

An enabling legislation

Count of all work packageable things for enabling legislation with ID HYrHvhwp

# We declare the Parliament and ID namespaces.    
PREFIX : <https://id.parliament.uk/schema/>
PREFIX id: <https://id.parliament.uk/>

# We select the properties we want to appear in results.
# If all properties are required, an asterisk can be used between SELECT and WHERE instead of listing properties.
# We count the number of distinct work packageable things for an item of enabling legislation.
SELECT (COUNT(DISTINCT ?workPackagedThing) AS ?count) WHERE {

# We find all enabling legislation and their names.   
  ?act a :ActOfParliament;
  :actOfParliamentName ?name.

# We specify that the enabling legislation may, or may not, have a number, year, royal assent date and URL.
  OPTIONAL {
    ?act :actOfParliamentNumber ?number
  }
  OPTIONAL {
    ?act :actOfParliamentYear ?year
  }
  OPTIONAL{ 
   ?act :actOfParliamentRoyalAssentDate ?date
  }
  OPTIONAL {
    ?act :actOfParliamentUrl ?url
  }
  
  # We filter the results to only include enabling legislation with ID HYrHvhwp.
  FILTER ( ?act IN ( id:HYrHvhwp ) )

# We find all work packaged things of the enabling legislation and their names.
  ?act :enabling ?workPackagedThing. 
  ?workPackagedThing :name ?workPackagedThingName. 
  }

Work packageable things for enabling legislation with ID HYrHvhwp

# We declare the Parliament and ID namespaces.    
PREFIX : <https://id.parliament.uk/schema/>
PREFIX id: <https://id.parliament.uk/>
      
# We select the properties we want to appear in results.
# If all properties are required, an asterisk can be used between SELECT and WHERE instead of listing properties.
SELECT ?workPackagedThing ?workPackagedThingName ?businessItemDate ?procedure ?procedureName WHERE {

# We find all enabling legislation and their names.  
  ?act a :ActOfParliament.
  ?act :actOfParliamentName ?name.

# We specify that the enabling legislation may, or may not, have a number, year, royal assent date and URL. 
  OPTIONAL {
    ?act :actOfParliamentNumber ?number
  }

OPTIONAL {
    ?act :actOfParliamentYear ?year
  }

OPTIONAL{ 
   ?act :actOfParliamentRoyalAssentDate ?date
  }
  OPTIONAL {
    ?act :actOfParliamentUrl ?url
  }
  
  # We filter the results to only include enabling legislation with ID HYrHvhwp.
  FILTER ( ?act IN ( id:HYrHvhwp ) )
  
  # We find all work packaged things of the enabling legislation and their names, and the work packages of the work packaged things.
  ?act :enabling ?workPackagedThing. 
  ?workPackagedThing :name ?workPackagedThingName;
  :workPackagedThingHasWorkPackage ?workPackage.
  
  # We find the making available business item, if there is one, of the work packages and it's date.
  OPTIONAL {
    ?workPackage :workPackageHasBusinessItem ?businessItem .
    ?businessItem :businessItemHasProcedureStep ?step;
    :businessItemDate ?businessItemDate.
    FILTER ( ?step IN ( id:isWn7s3K, id:cspzmb6w, id:ITNO9JWr, id:otscOTzB ) )
  }
  
  # We find the procedure of the work packages and the procedure names.
  ?workPackage :workPackageHasProcedure ?procedure.
  ?procedure :name ?procedureName.
                     
} 
# We order the results by business item date in descending order.  
ORDER BY DESC(?businessItemDate)          
# We limit the number of results returned and we offset the results returned by a specified number.          
LIMIT 20 OFFSET 0