Safety of Sports Grounds (Designation) (Amendment) (England) Order 2026 Documents

A work package focussed on the Safety of Sports Grounds (Designation) (Amendment) (England) Order 2026, made available on 16 July 2026, subject to the Made negative procedure. Scrutiny period described by Bicameral instruments (clock stops if both Houses rise).

Read the legislation.

Read the Explanatory Memorandum.

No documents are yet available.

Subscribe to RSS

Work package identifier

https://id.parliament.uk/PfRmesv1

SPARQL queries used by this page

A work package

# We declare the Parliament and ID namespaces.
        PREFIX : <https://id.parliament.uk/schema/>
        PREFIX id: <https://id.parliament.uk/>

# We select the properties we want to appear in results. The asterisk will select all properties from the query.
        SELECT * WHERE {
        # We find all papers with a name and a work package.
        ?paper a :WorkPackagedThing .  
        ?paper :name ?paperName ;
        :workPackagedThingHasWorkPackage ?workPackage.

# We specify that a paper might have a web link. 
        OPTIONAL {?paper :workPackagedThingHasWorkPackagedThingWebLink ?workPackagedThingWebLink.}
  
        # We specify that a paper might have a laying with a laid date. We also specify that a laying will have a procedure step.  
        OPTIONAL {?paper :laidThingHasLaying ?laying.
        ?laying :layingDate ?laidDate;
        :businessItemHasProcedureStep ?step.
    
        # We specify that the laying will have one of two steps - 'Laid before the House of Commons' or 'Notification from Department announcing the publication of the draft laid before the House of Commons'. 
        FILTER (?step in (id:isWn7s3K, id:cspzmb6w))}

# We look for work packages with a procedure and the procedure's name.   
        ?workPackage :workPackageHasProcedure ?procedure.
        ?procedure :name ?procedureName.

# We specify that a work package may have a calculcation style with it's name but that a calculation style is not required. 
        OPTIONAL{ ?workPackage :workPackageHasCalculationStyle ?calculationStyle. 
        ?calculationStyle :name ?calculationStyleName. }

# We specify a specific work package using its ID. 
        FILTER (?workPackage in (id:PfRmesv1))
        }

A list of business items in a work package with a link, actualising steps in the reading list collection

PREFIX : <https://id.parliament.uk/schema/>
PREFIX id: <https://id.parliament.uk/>

SELECT
    ?paper
    ?paperName
    ?workPackage
    ?businessItem
    ?businessItemLink
    ?businessItemProcedureStep
    ?businessItemDate
    ?businessItemProcedureStepName
    ?legislature
    ?legislatureName
    ?commonsId
    ?lordsId
    ?documentTypeCollection
    ?documentTypeCollectionName

WHERE {

?paper a :WorkPackagedThing ;
           :name ?paperName ;
           :workPackagedThingHasWorkPackage ?workPackage .

FILTER (?workPackage IN (id:PfRmesv1))

?workPackage :workPackageHasBusinessItem ?businessItem .

?businessItem
        :businessItemHasBusinessItemWebLink ?businessItemLink ;
        :businessItemHasProcedureStep ?businessItemProcedureStep .

OPTIONAL {
        ?businessItem :businessItemDate ?businessItemDate .
    }

?businessItemProcedureStep
        :procedureStepHasProcedureStepCollectionMembership/
        :procedureStepCollectionMembershipHasProcedureStepCollection
        id:Ji8bWVUj .

?businessItemProcedureStep
        :name ?businessItemProcedureStepName .

OPTIONAL {
        ?businessItemProcedureStep
            :procedureStepInLegislature ?legislature .

?legislature :name ?legislatureName .
    }

OPTIONAL {
        ?businessItemProcedureStep
            :procedureStepHasHouse ?commonsId .

FILTER (?commonsId = id:1AFu55Hs)
    }

OPTIONAL {
        ?businessItemProcedureStep
            :procedureStepHasHouse ?lordsId .

FILTER (?lordsId = id:WkUWUBMx)
    }

?businessItemProcedureStep
            :procedureStepHasProcedureStepCollectionMembership/
            :procedureStepCollectionMembershipHasProcedureStepCollection
            ?documentTypeCollection .

VALUES ?documentTypeCollection {
            id:YeyqTPT6
            id:yuLI4KIY
            id:GJyoVAV5
            id:SHG1bKCe
            id:ZimrKJ0K
            id:KMGLDo11
            id:7CBVQcZF
            id:m7fzgEd2
        }

?documentTypeCollection
            :name ?documentTypeCollectionName .

}

ORDER BY ?businessItemDate